Kurven sehen und verstehen

Haftendorn April 2017, http://www.kurven-sehen-und-verstehen.de

Nephroide und ihre Pedalkurven (Fußpunktkurven)

Quit

Damit die Lösungen unabhängig sind, lasse ich die nötigen  Teile aus der Evoluten-Datei hier stehen.

Nephroide, doppelt achsensymmetrisch

x[t_]:=(a/2)(3 Cos[t]+Cos[3t])
y[t_]:=(a/2)(3 Sin[t]+Sin[3t])

Bild

a=1;nephrobild=ParametricPlot[{x[t],y[t]},{t,0,2Pi}, PlotStyle->{Thickness[0.02], Green}]
a=.

Eliminierung von t (siehe bei Evolute)

TrigExpand[Cos[3t]]
TrigExpand[Sin[3t]]

Eliminate[{x==(a/2)(3c+(c^3)-3 c (s^2)),y== (a/2)(3s - (s^3)+3 (c^2) s ), (s^2)+(c^2)==1},{s,c}]//FullSimplify

4 (a^6)+3 (a^4) (5 (x^2)-4 (y^2))+12 (a^2) ((((x^2)+(y^2)))^2)==4 ((((x^2)+(y^2)))^3)
implizite kartesische Gleichung der Nephroide, Spitzenabstand a

Schnitte mit den Achsen (siehe bei Evolute)

4 (a^6)+3 (a^4) (5 (x^2)-4 (y^2))+12 (a^2) ((((x^2)+(y^2)))^2)==4 ((((x^2)+(y^2)))^3)/.y->0

Solve[4 (a^6)+15 (a^4) (x^2)+12 (a^2) (x^4)==4 (x^6),{x}]

4 (a^6)+3 (a^4) (5 (x^2)-4 (y^2))+12 (a^2) ((((x^2)+(y^2)))^2)==4 ((((x^2)+(y^2)))^3)/.x->0

Solve[4 (a^6)-12 (a^4) (y^2)+12 (a^2) (y^4)==4 (y^6),{y}]

Zeichnung

a=2;ContourPlot[4 (a^6)+3 (a^4) (5 (x^2)-4 (y^2))+12 (a^2) ((((x^2)+(y^2)))^2)==4 ((((x^2)+(y^2)))^3),{x,-4,4},{y,-3,3}, AspectRatio->Automatic]
a=.

Rechnungen zu Tangenten

D[x[t],t]
D[y[t],t]

Steigung bei Parameterwert t.

m[t_]:=-(( Cos[t]+ Cos[3t])/(Sin[t]+Sin[3 t]))

a=2;Plot[{m[t],x[t],y[t]},{t,0,2Pi},PlotRange->{-6,6}] 
a=.(* y oliv *)

Tangentengleichung

m[t_]:=-(( Cos[t]+ Cos[3t])/(Sin[t]+Sin[3 t]))    (* Herleitung aus (OverDot[y])/(OverDot[x]) wie bei Evolute*)

(tang[x_]:=m[t](x-x[t])+y[t]//FullSimplify) ;tang[x]

Csc[t] (a-(1/2) x Cos[2 t] Sec[t])//Expand   (* Steigung Cot(2t), siehe Probe*)

Lote durch den Pol Z=(p,d) auf die Tangenten

lot[x_]:=((( Sin[t]+ Sin[3t])/(Cos[t]+Cos[3 t]))(x-p)+d//FullSimplify); lot[x]

TrigExpand[(1/2)Cos[2 t] Csc[t] Sec[t]- Cot[2t]]  (* als Probe*)

Schnitt der Lote mit den Tangenten

mit der üblichen Substitution

lo=Solve[lot[x]==tang[x],x]//FullSimplify

lot[x]/.lo[[1,1]]

{a=1,p=-2,d=1};
ParametricPlot[{(1/2) Sin[4 t] (-d+a Csc[t]+p Tan[2 t]),d+Tan[2 t] (-p+(1/2) Sin[4 t] (-d+a Csc[t]+p Tan[2 t]))},{t,0,2Pi}]
{a=.,p=.,d=.};

Berechnung der Pedalkurve

xt=x==(1/2) (Sin[4 t]//TrigExpand ) (-d+a Csc[t]+p (Tan[2 t]//TrigExpand))

xsc=x==(1/2) (4 ((Cos[t])^3) Sin[t]-4 Cos[t] ((Sin[t])^3)) (-d+a Csc[t]+((2 p Cos[t] Sin[t])/(((Cos[t])^2)-((Sin[t])^2))))/.{Sin[t]->s, Cos[t]->c , Csc[t]->(1/s)}//FullSimplify

yt=y==d+(Tan[2 t]//TrigExpand) (-p+x)

ysc=yt/.{Sin[t]->s, Cos[t]->c}

Die beiden Schnittgleichungen  und (c^2)+(s^2)==1

pedal=Subtract@@(Eliminate[{xsc,ysc,(c^2)+(s^2)==1 },{s,c}]//FullSimplify)

pedalA=(pedal/.d->0 //FullSimplify);

pedalAchse=4(a^2)((y^2)+(((x-p))^2))((a^2)(y^2)-((((x^2)+(y^2)-p x ))^2))+(((-p x+(x^2)+(y^2)))^4) ;

pedalA-pedalAchse//FullSimplify  (* zur Sicherheit!*)

{a=1,p=-4};pedBild=ContourPlot[pedalAchse==0//Evaluate,{x,-4.2,2.5},{y,-4,4}, ContourStyle->Red, PlotPoints->100, AspectRatio->Automatic]
{a=.,p=.};

Show[pedBild,nephrobild, Graphics[{{PointSize[0.03],Point[{-4,0}]},
{Thickness[0.008],RGBColor[0.5,0,1],Circle[{-4,0},6]}}]]

Der Pol Z im Ursprung

pedalAchseN=pedalAchse/.p->0

Einen Faktor ((x^2)+(y^2)) kann man herausziehen. da sie Kurve als F(x,y)=0 geschrieben wird, sagt dieser Faktor nur, dass der Ursprung erreicht wird. Das ist bei pedalUr=0 auch klar.

pedalUr=(((((x^2)+(y^2)))^3)+4(a^2)((a^2)(y^2)-  ((((x^2)+(y^2)))^2)));

a=1; ContourPlot[pedalUr==0//Evaluate,{x,-2.5,2.5},{y,-2,2}, AspectRatio->Automatic]
a=.;